GalgasLab/logoPlayer/galgas-sources/logoPlayer-syntax.galgas

syntax logoPlayer_syntax (logoPlayer_lexique) {

  rule <start_symbol> {
    # Routine definition
    $PROGRAM$
    @routineMap routineArray = {}
    <routines> !? routineArray

    $BEGIN$
    <instructions>
    $END$
    $.$
  }

  rule <routines> ?! @routineMap routineArray {
    repeat
    while
      <routine> !? routineArray
    end
  }

  rule <routine> ?! @routineMap ioRoutineArray {
    $ROUTINE$
    $identifier$ ?let @lstring routineId
    log routineId
    $BEGIN$
    <instructions>
    $END$
  } 

  rule <instructions> {
    repeat
    while
      <instruction>
    end
  }

  rule <instruction> {
    select
      <move>
    or
      <set_pen>
    or
      <call_routine>
    end
    $;$
  }

  rule <move> {
    select
      $FORWARD$
    or
      $ROTATE$
    end
    $integer$ ?let @luint moveLen
    log moveLen
  }

  rule <set_pen> {
    $PEN$
    select
      $UP$
    or
      $DOWN$
    end
  }

  rule <call_routine> {
    $CALL$
    $identifier$ ?let @lstring routineId
  }
    
}