GalgasLab/logoPlayer/galgas-sources/logoPlayer-syntax.galgas

syntax logoPlayer_syntax (logoPlayer_lexique) {

  rule <start_symbol> {
    # Routine definition
    $PROGRAM$

    @routineMap routineArray = {}
    @instructionList baseProgram = {}

    <routines> !? routineArray

    $BEGIN$
    <instructions> !? routineArray !? baseProgram
    $END$
    $.$
  }

  rule <routines> ?! @routineMap routineArray {
    repeat
    while
      <routine> !? routineArray
    end
  }

  rule <routine> ?! @routineMap ioRoutineArray {
    $ROUTINE$
    $identifier$ ?let @lstring routineId

    @instructionList routineProgram = {}

    $BEGIN$
    <instructions> !? ioRoutineArray !? routineProgram
    $END$
    [ !? ioRoutineArray insertKey !routineId ]
  } 

  rule <instructions> ?! @routineMap ioRoutineArray ?! @instructionList program {
    repeat
    while
      <instruction> !? ioRoutineArray !? program
    end
  }

  rule <instruction> ?! @routineMap ioRoutineArray ?! @instructionList program {
    select
      <move> !? program
    or
      <set_pen> !? program
    or
      <call_routine> !? ioRoutineArray !? program
    end
    $;$
  }

  rule <move> ?! @instructionList program {
    select
      <move_forward> !? program
    or
      <move_rotate> !? program
    end
  }

  rule <move_forward> ?! @instructionList program {
    $FORWARD$
    $integer$ ?let @luint moveLen

    @instruction move = @forward.new { !moveLen }
    program += !move
  }

  rule <move_rotate> ?! @instructionList program {
    $ROTATE$
    $integer$ ?let @luint moveAngle

    @instruction move = @rotate.new { !moveAngle }
    program += !move
  }

  rule <set_pen> ?! @instructionList program {
    $PEN$
    @instruction setPen
    select
      $UP$
      setPen = @penUp.new {}
    or
      $DOWN$
      setPen = @penDown.new {}
    end
    program += !setPen
  }

  rule <call_routine> ?! @routineMap ioRoutineArray ?! @instructionList program {
    $CALL$
    $identifier$ ?let @lstring routineId
    [ ioRoutineArray searchKey !routineId ]
  }
    
}