MightyLiners2/Player.gd

extends Area2D

# Nodes
var grid:TileMap
onready var tween = $Tween

# Misc
var cell_size
var cell_half_size
var alive = false

# Enum
enum Direction {
	UP = 0
	RIGHT = 1
	DOWN = 2
	LEFT = 3
}

enum Side {
	LEFT = -1
	RIGHT = 1
}

# Movement
var posix
var posiy
var dirx = 0
var diry = 0

export var dire = Direction.UP
var dire_delta = 0

var target_pos

# Controls
export var turn_left_action:String
export var turn_right_action:String

func _ready():
	add_to_group("players")
	spring()

	assert(grid)
	assert(turn_left_action)
	assert(turn_right_action)

	cell_size = int (grid.get_cell_size().x)
	cell_half_size = cell_size / 2

	posix = int (position.x / 64)
	posiy = int (position.y / 64)

	update_dirxy()

	tween.connect_into(self)

func _unhandled_input(event):
	if event.is_pressed():
		if event.is_action(turn_left_action):
			tween.rotate_char(self, rotation_degrees - 90)
			tween.start()

			dire_delta = Side.LEFT
			get_tree().set_input_as_handled()
		elif event.is_action(turn_right_action):
			tween.rotate_char(self, rotation_degrees + 90)
			tween.start()

			dire_delta = Side.RIGHT
			get_tree().set_input_as_handled()

func _on_game_start():
	move()

func _on_tween_completed(_o, key):
	if (key == ":position"):
		move()

func _on_crash(body):
	die()
	generate_wall()
	grid.set_cell(posix, posiy, 2)

func generate_wall():
	grid.set_cell(posix - dirx, posiy - diry, 1)

func move():
	if !alive:
		return

	generate_wall()

	if dire_delta == Side.LEFT and !has_block_on(Side.LEFT):
		# TODO Undo sprite turn if blocked
		dire += dire_delta
		if dire < 0:
			dire = 3

	elif dire_delta == Side.RIGHT and !has_block_on(Side.RIGHT):
		dire += dire_delta
		if dire > 3:
			dire = 0

	update_dirxy()
	dire_delta = 0

	posix += dirx
	posiy += diry

	target_pos = Vector2(posix * cell_size + cell_half_size, posiy * cell_size + cell_half_size)
	tween.move_char(self, target_pos)
	tween.start()

func has_block_on(left_or_right:int):
	var bposx:int = posix - diry * left_or_right
	var bposy:int = posiy + dirx * left_or_right

	# TODO : use enum for blocks
	return grid.get_cell(bposx, bposy) == 1

func update_dirxy():
	dirx = 0
	diry = 0
	if dire == Direction.UP:
		diry -= 1
	elif dire == Direction.RIGHT:
		dirx += 1
	elif dire == Direction.DOWN:
		diry += 1
	elif dire == Direction.LEFT:
		dirx -= 1
	else:
		push_error("dire out of range")

func die():
	alive = false
	remove_from_group("living")

func spring():
	alive = true
	add_to_group("living")

func is_alive():
	return alive