AlphaRaquette/godot/composants/interface/pause/pause_menu.gd

extends Control


const curseur_main: Texture = preload("res://composants/interface/curseur/hand_point.png")


func _ready() -> void:
	Input.set_custom_mouse_cursor(curseur_main, Input.CURSOR_POINTING_HAND)


func activer_pause() -> void:
	get_tree().set_pause(true)
	musique_en_retrait(true)
	show()
	%Reprendre.grab_focus()


## Desactiver pause
func reprendre() -> void:
	hide()
	musique_en_retrait(false)
	get_tree().set_pause(false)
	Input.set_custom_mouse_cursor(null, Input.CURSOR_ARROW)


## Active ou desactive l'effet pour rendre la musique moins presente
func musique_en_retrait(effet_actif: bool) -> void:
	AudioServer.set_bus_effect_enabled(2, 1, effet_actif)


func _unhandled_input(event: InputEvent) -> void:
	if event.is_action_released("ui_pause"):
		if get_tree().is_paused():
			reprendre()
		else:
			activer_pause()


func _quand_bouton_reprendre_est_presse():
	reprendre()


func _quand_bouton_retour_titre_est_presse():
	reprendre()
	get_tree().reload_current_scene()


func _quand_bouton_quitter_est_presse():
	get_tree().quit()